Jump to content

[RELz] Mertz's WizBAIN thread


Beermotor

Recommended Posts

You are welcome... ;)

 

I've been working on a bit of a SSE guide and have ran across a few mods which were severely mishandled in their archiving so I've been repacking them, updating the FOMODs (fixing them in some cases), writing Wizards for the mods, and offering the new archives to the authors for upload. Bellyache's was the first one I did. I didn't write a wizard for it, though, because that would have been a bit insane for my tastes. Glad someone took on the task! Veydosebrom was also my doing so you can think me if there happen to be any issues there. Haha! Also recently updated was CC's HQ Septim that I rewrote for CC.

 

The following I've done and offered to the authors, but they have yet to put them up:

  • Immersive Sounds - Compendium (author is planning to upload, he's just been...lazy :) )
  • Enhanced Blood Textures (no word from author yet.)
  • Tempered Skins for Males - Dressed Version (no word from author yet.)

 

I honestly don't understand why authors don't package the mods up correctly for WB users. Whether they write a wizard or not, it's super simple to at least package the archive in a BAIN readable structure.

Link to comment
Share on other sites

3 hours ago, TechAngel85 said:

You are welcome... ;)

 

I've been working on a bit of a SSE guide and have ran across a few mods which were severely mishandled in their archiving so I've been repacking them, updating the FOMODs (fixing them in some cases), writing Wizards for the mods, and offering the new archives to the authors for upload. Bellyache's was the first one I did. I didn't write a wizard for it, though, because that would have been a bit insane for my tastes. Glad someone took on the task! Veydosebrom was also my doing so you can think me if there happen to be any issues there. Haha! Also recently updated was CC's HQ Septim that I rewrote for CC.

 

The following I've done and offered to the authors, but they have yet to put them up:

  • Immersive Sounds - Compendium (author is planning to upload, he's just been...lazy :) )
  • Enhanced Blood Textures (no word from author yet.)
  • Tempered Skins for Males - Dressed Version (no word from author yet.)

 

I honestly don't understand why authors don't package the mods up correctly for WB users. Whether they write a wizard or not, it's super simple to at least package the archive in a BAIN readable structure.

First of all, Hell yeah! That's fantastic. :) I actually just messaged Merkcy about doing a wizard rewrite for the new Veydosebrom right before I came over here.

I'm delighted you're getting into writing Wizards. If you need any help this is probably the thread to ask it in. I can't say I'm a guru, but I'll do what I can to help and if not, we can summon the elder gods. 

So I have a pretty good idea on the structure thing - there are at least two tools out there for automatically generating FOMODs, and these seem to be the most predominant from what I can divine:

FOMOD Creation Tool

FOMOD Creator

Neither of them mention anything about BAIN structure or proper packaging in their documentation. Apparently these are new people that have never known anything other than NMM/FOMM/MO and have no idea that there has been a packaging standard since at least 2009 for formatting mods that the community has long agreed upon.

The solution for this is education and not antagonism of course. I'm not sure how to approach it without sounding preachy though.

 

 

Link to comment
Share on other sites

Yes me too, although I use vim for a lot of stuff as well.  I just need a syntax highlighter for BAIN and I'll be set. :)

I'm glad you linked that FOMOD creator from Ganda, I actually found his stuff while looking for Python-based FOMOD parsers and was impressed with this work. He's done some fairly extensive work with creation, testing, validation, and so on that could be educational later on when FOMOD conversion is added to WB. 

Back to BAIN wizards, if you don't get any response from the mod authors on the latter two,  please post them on here and I'll be happy to link back to them from the first post.

:horker:

Link to comment
Share on other sites

I can do that, but I don't think they'll be of much use. My wizards are set up for a restructured directory in mind. I like to convert the file structure to a complex BAIN structure so users have the choice of using the wizard or just quickly selecting the sub-packages they want.

Link to comment
Share on other sites

1 hour ago, TechAngel85 said:

I can do that, but I don't think they'll be of much use. My wizards are set up for a restructured directory in mind. I like to convert the file structure to a complex BAIN structure so users have the choice of using the wizard or just quickly selecting the sub-packages they want.

Ah then you can create a BCF for those situations. Have you ever tried making one? There was a problem with BCF handling in some older versions of WB but it has been corrected in the most recent dev/wip builds. 

Link to comment
Share on other sites

11 minutes ago, lmstearn said:

Try this for N++ syntax

Although my flavour is dark themed so using Hinkerloden for everything. :P

Yes that is fantastic and it's been awesome while creating wizards. I'm also trying to put one together for Vim. :) 

Link to comment
Share on other sites

Actually this is what I'm talking about:

vim-highlighting.thumb.PNG.bf6507485cfab244c0d1f37219479839.PNG

That's just the Python syntax highlighting for Vi/Vim/NeoVim which is similar enough to get some work done.

Link to comment
Share on other sites

I did Vivid Weathers today and offered it to Mangaclub. I'm sure he'll upload it whenever he sees the message.

  • Like 2
Link to comment
Share on other sites

10 hours ago, Beermotor said:

Actually this is what I'm talking about:

vim-highlighting.thumb.PNG.bf6507485cfab244c0d1f37219479839.PNG

That's just the Python syntax highlighting for Vi/Vim/NeoVim which is similar enough to get some work done.

That's pretty. For N++ would have been nice to add a keyword list, auto-indenting, auto complete- even a little parser to test the script. But it's awkward without the extra functionality of their official languages list. Perhaps VIM's more flexible. Remember it from the Amiga- it was a cool program then.

14 hours ago, alt3rn1ty said:

...

And an Editor which was programmed specifically for Skyrim - Skyrim Script Editor

Features : "- Ask and you will get it"

Wow, it's still being updated. Looks like a much better alternative to the N++ compiler even though it has been recently updated.

Link to comment
Share on other sites

10 hours ago, Sladen2019 said:

I can take a whack at XPMSE, I actually did a prototype and I cannot remember why I paused on it. I'll see what I can do. It may require a BCF due to structuring however.

 

8 hours ago, TechAngel85 said:

I did Vivid Weathers today and offered it to Mangaclub. I'm sure he'll upload it whenever he sees the message.

Outstanding. :) 

Link to comment
Share on other sites

I think either I'm dumb or I've encountered a quirk, maybe I can get some advice.

Due to the way the XPMSSE mod is structured, there are pretty much pre-defined combinations of dagger, sword, and quiver locations. This is necessary because there is only one skeleton.nif file and many combinations of the three.

So I was going to set up something where if the user chose to have a hip dagger, normal sword, and belt quiver, it would output "101". All defaults would be "000", only quiver would be "001" and so on. Basically flipping a bit if it was true.

Here's my code:

Case "Joy of Perspective"
         SelectOne "Quiver Position\n\nHere you choose how your quivers should be placed, this only applies when using the skeletons from the default skeleton file path. Races\\NPCs using a seperate skeleton file path are not affect and you have to replace their skeletons manually\n\nSelect only one of the following:",\
            "|Default Quivers","Choose this option if you want your quiver\\bolts placed at the default position","Fomod\\Screens\\XPMSSE_Banner.png",\
            "Hip-fastened Quivers","Choose this option if you want your quiver\bolts placed like in \"Belt-Fastened Quivers\" edited by Chesko and Ninivekha \[NEXUS ID: 1182\].","Fomod\\Screens\\Chesko.png"
            Case "Default Quivers"
                BowQuiverBolt = str('0')
                Break
            Case "Hip-fastened Quivers"
                BowQuiverBolt = str('1')
                Break
        EndSelect
        SelectOne "Dagger Position\n\nHere you choose how your Dagger should be placed, this only applies when using the skeletons from the default skeleton file path. Races\\NPCs using a seperate skeleton file path are not affect and you have to replace their skeletons manually\n\nSelect only one of the following:",\
            "|Default Dagger","Choose this option if you want your dagger placed at the default position.","Fomod\\Screens\\XPMSSE_Banner.png",\
            "Dagger on Back Hip","Choose this option if you want your dagger placed at the back hip.","Fomod\\Screens\\BHD.png"
            Case "Default Dagger"
                DaggerBack = str('1')
                Break
            Case "Dagger on Back Hip"
                DaggerBack = str('1')
                Break
        EndSelect
        SelectOne "Sword Placement",\
            "|Default Sword Placement","Default spot for your sword","",\
            "Sword on back","Sword on your back",""
                Case "Default Sword Placement"
                    SwordBack = str('0')
                    Break
                Case "Sword on Back"
                    SwordBack = str('1')
                    Break
        EndSelect
    Break
EndSelect


LoadOut = BowQuiverBolt + DaggerBack + SwordBack

Note LoadOut

So when you get to the end of the wizard, if you have selected all of the optional choices (toggled them all to 1) , the "Note" should should be "111". Instead I'm getting "11SwordBack". I've tried compound assignment, I tried changing them to integers instead of strings but that just crashed the parser. 

I'm kind of stumped, but part of that could be due to being awake for 18 hours.

Does anyone have any ideas?

Link to comment
Share on other sites

Maybe WB has a special Room 101?

room101.jpg

But jesting aside, define variables first

   BowQuiverBolt = 000
   DaggerBack = 000
   SwordBack = 000

Then BowQuiverBolt can be either 100 or 000

DaggerBack can be 010 or 000

SwordBack can be 001 or 000

Adding these with + should get the req'd result.

Link to comment
Share on other sites

15 hours ago, lmstearn said:

Maybe WB has a special Room 101?

But jesting aside, define variables first

   BowQuiverBolt = 000
   DaggerBack = 000
   SwordBack = 000

Then BowQuiverBolt can be either 100 or 000

DaggerBack can be 010 or 000

SwordBack can be 001 or 000

Adding these with + should get the req'd result.

What's in Room 101? Either XPMSSE or SMIM.  ;)

Thank for that suggestion. It does do the digits properly and I'll slip that one into my bag of tricks. I've actually sobered up and I'm taking a different tack as an experiment today using true/false values.

What I'm running into however is unusual (at least I've not run into it yet)  and it is so weird I think I'm doing something wrong.

I have three vars that can be true/false. They are naturally false.

    bBowQuiverBolt = False  ; Belt fastened quiver?
    bDaggerHip = False ; Dagger on hip?
    bSwordBack = False ; Sword on back?

Later at payload building time when I'm getting ready to build out my 'SelectSubPackage' payload I do this (this is abbreviated of course) :
 

	If bBowQuiverBolt == False and bDaggerHip == False and bSwordBack == False
		SelectSubPackage  '07 XPMSSE'
		SelectSubPackage '07 XPMSSE - 1st Person'
	Elif  bBowQuiverBolt and bDaggerHip == False and bSwordBack == False
		SelectSubPackage '07 XPMSSE - BFQ'
		SelectSubPackage '07 XPMSSE - BFQ - 1st Person'
		SelectSubPackage '08 BFQ'
         <SKIP A BUNCH OF THESE FOR BREVITY>
	Elif bBowQuiverBolt and bDaggerHip and bSwordBack
		SelectSubPackage '07 XPMSSE - SOB - BHD - BFQ'
		SelectSubPackage '07 XPMSSE - SOB - BHD - BFQ - 1st Person'
		SelectSubPackage '08 BFQ'
		SelectSubPackage '08 BHD'
		SelectSubPackage '08 SOB'
	EndIf

What is happening is no matter what the user selects, the last variable (bSwordBack) is always ignored. It is like I cannot stack three ANDs together.

For example the bottom one where all three variables are true, only 'bBowQuiverBolt' and 'bDaggerHip' are actually toggled and 'bSwordBack' is completely ignored.  If I juggle the variables around, the far right-most variable is always ignored.

Like I said, this is so repeatable that I'm certain I have a syntax error somewhere or I'm doing it wrong.

 

 

 

Link to comment
Share on other sites

Ah the check for these is a bit different, you set them false initially, then somewhere among your questions to the user you will set them as true

But then when it comes to the decision making you check if the value has become true (without using the word true or =)

;==my wiz==

blag = false

selectmany

case 1

do action

blag = true

case 2

do action

endselect

If blag

do other action

Endif

 

The "If Blag" near the end there is asking if blag is true, if it is "Do other action" happens. If it is still false "Do other action" doesn't happen. You dont need to put "If blag == true", just "If blag"

 

Here's my Alt Navetsea UNP Seamless (Yes I know, an unfortunate abbreviation I only realised after publishing :) ) wizard

Look for how NavBaseFace and NuskaBaseFace are used

(Just after "SelectOne "CHOOSE A FACE SET YOU WANT TO INSTALL",\")

 

;== Alt Navetsea UNP Seamless - BaIn Wizard by Alt3rn1ty ==

RequireVersions "", "", "", "295"

DeSelectAll

NavBaseFace = False
NuskaBaseFace = False

;== Welcome screen ==

SelectOne "ALT NAVETSEA UNP SEAMLESS - BAIN INSTALLATION WIZARD",\
    "|WELCOME","\nCLICK OPTIONS ABOVE TO REVIEW WHAT THIS INSTALLER INCLUDES OR ..\n\nCLICK NEXT TO CONTINUE THE INSTALLATION","FOMod\\screenshot.jpg",\
    "DESCRIPTION","\nALT NAVETSEA UNP SEAMLESS V5, ALL-IN-ONE NUDE FEMALE BODY REPLACER, INCLUDES UNP MESHES, REWORKED NAVETSEA TEXTURES AND OPTIONS, AND REWORKED NUSKA ADDITIONAL HEAD TEXTURES TO CHOOSE FROM.\n\nCLICK NEXT TO CONTINUE THE INSTALLATION","FOMod\\screenshot.jpg",\
    "VERSION","\nVERSION 5; BODY MESH CHOICES, NOW YOU CAN CHOOSE BETWEEN UNP 1.2 MESH, B2 MESH OR SKINNY MESH. ALSO MADE OLD FOLKS NORMALS OPTIONAL SO YOU DO NOT NEED TO INSTALL NAVETSEAS YOUNGER LOOKING VERSIONS\n\nCLICK NEXT TO CONTINUE THE INSTALLATION","FOMod\\screenshot.jpg",\
    "CREDITS","\nBAIN PACKAGE, WIZARD AND TEXTURE REWORK BY ALT3RN1TY\n\nSPECIAL THANKS TO ..\n\nDIMON99 FOR UNP MESHES\n\nNAVETSEA FOR THE ORIGINAL TEXTURES\n\nNUSKA FOR ADDITIONAL FACE TEXTURE OPTIONS\n\nCLICK NEXT TO CONTINUE THE INSTALLATION","FOMod\\screenshot.jpg"
EndSelect

;== Select Body Meshes ==

SelectOne "CHOOSE A BODY MESH YOU WANT TO INSTALL",\
    "UNP 1.2 MESH","\n\nCHOOSE WHICH BODY MESH YOU REQUIRE\n\nCLICK NEXT TO CONTINUE THE INSTALLATION","FOMod\\images\\UNP 1.2 mesh.jpg",\
    "|UNP B2 MESH","\n\nCHOOSE WHICH BODY MESH YOU REQUIRE\n\nCLICK NEXT TO CONTINUE THE INSTALLATION","FOMod\\images\\UNP B2 mesh.jpg",\
    "UNP SKINNY MESH","\n\nCHOOSE WHICH BODY MESH YOU REQUIRE\n\nCLICK NEXT TO CONTINUE THE INSTALLATION","FOMod\\images\\UNP Skinny mesh.jpg"
    Case "UNP 1.2 MESH"
        SelectSubPackage "10 UNP Base Meshes"
        Break
    Case "UNP B2 MESH"
        SelectSubPackage "10 UNP Base Meshes - B2 mesh"
        Break
    Case "UNP SKINNY MESH"
        SelectSubPackage "10 UNP Base Skinny Meshes"
        Break
EndSelect

;== Select 1st Person Hand Mesh ==

SelectOne "CHOOSE HAND MESHES",\
    "UNP 3RD PERSON HAND MESH","\n\nCHOOSE THIS OPTION TO INSTALL A THIRD PERSON FEMALE HAND MESH ( AS SEEN ON NPCs ), BUT THE 1ST PERSON HAND MESH REMAINS A VANILLA GAME MESH\n\nCLICK NEXT TO CONTINUE THE INSTALLATION","FOMod\\images\\1st Person Hand Mesh Vanilla.jpg",\
    "|ALL UNP HAND MESHES","\n\nCHOOSE THIS OPTION IF YOU ALSO WANT TO INSTALL A UNP 1ST PERSON FEMALE HAND MESH ( ASWELL AS THE UNP THIRD PERSON FEMALE HAND MESH )\n\nCLICK NEXT TO CONTINUE THE INSTALLATION","FOMod\\images\\1st Person Hand Mesh UNP.jpg"
    Case "UNP 3RD PERSON HAND MESH"
        SelectSubPackage "15 3rd Person Female Hand mesh - UNP"
        Break
    Case "ALL UNP HAND MESHES"
        SelectSubPackage "16 1st and 3rd Person Female Hand meshes - UNP"
        Break
EndSelect

;== Select Body Textures ==

SelectSubPackage "20 Body Base Textures - Shaved Feminine Default"

SelectOne "CHOOSE A BODY TEXTURE YOU WANT TO INSTALL",\
    "SHAVED","\n\nCHOOSE WHICH BODY TEXTURE YOU REQUIRE\n\nCLICK NEXT TO CONTINUE THE INSTALLATION","FOMod\\images\\Pubic 1 Shaved.jpg",\
    "LANDINGSTRIP","\n\nCHOOSE WHICH BODY TEXTURE YOU REQUIRE\n\nCLICK NEXT TO CONTINUE THE INSTALLATION","FOMod\\images\\Pubic 2 Landingstrip.jpg",\
    "STRIP","\n\nCHOOSE WHICH BODY TEXTURE YOU REQUIRE\n\nCLICK NEXT TO CONTINUE THE INSTALLATION","FOMod\\images\\Pubic 3 Strip.jpg",\
    "TRIM","\n\nCHOOSE WHICH BODY TEXTURE YOU REQUIRE\n\nCLICK NEXT TO CONTINUE THE INSTALLATION","FOMod\\images\\Pubic 4 Trim.jpg",\
    "|HAIRY","\n\nCHOOSE WHICH BODY TEXTURE YOU REQUIRE\n\nCLICK NEXT TO CONTINUE THE INSTALLATION","FOMod\\images\\Pubic 5 Hairy.jpg",\
    "HAIRY WILD","\n\nCHOOSE WHICH BODY TEXTURE YOU REQUIRE\n\nCLICK NEXT TO CONTINUE THE INSTALLATION","FOMod\\images\\Pubic 6 Hairy wild.jpg"
    Case "SHAVED"
        SelectSubPackage "30 Body skin - Pubic 1 Shaved"
        Break
    Case "LANDINGSTRIP"
        SelectSubPackage "30 Body skin - Pubic 2 Landingstrip"
        Break
    Case "STRIP"
        SelectSubPackage "30 Body skin - Pubic 3 Strip"
        Break
    Case "TRIM"
        SelectSubPackage "30 Body skin - Pubic 4 Trim"
        Break
    Case "HAIRY"
        SelectSubPackage "30 Body skin - Pubic 5 Hairy"
        Break
    Case "HAIRY WILD"
        SelectSubPackage "30 Body skin - Pubic 6 Hairy wild"
        Break
EndSelect

;== Select Body Normal map ==

SelectOne "CHOOSE A BODY NORMAL MAP YOU WANT TO INSTALL",\
    "|FEMININE","\n\nCHOOSE WHICH NORMAL MAP YOU REQUIRE\n\nCLICK NEXT TO CONTINUE THE INSTALLATION","FOMod\\images\\normal map 1 - Feminine.jpg",\
    "FEMININE TONED","\n\nCHOOSE WHICH NORMAL MAP YOU REQUIRE\n\nCLICK NEXT TO CONTINUE THE INSTALLATION","FOMod\\images\\normal map 2 - Feminine Arms Toned Abs.jpg",\
    "MUSCULAR","\n\nCHOOSE WHICH NORMAL MAP YOU REQUIRE\n\nCLICK NEXT TO CONTINUE THE INSTALLATION","FOMod\\images\\normal map 3 - Muscular body.jpg",\
    "MUSCULAR V2","\n\nCHOOSE WHICH NORMAL MAP YOU REQUIRE\n\nCLICK NEXT TO CONTINUE THE INSTALLATION","FOMod\\images\\normal map 4 - Muscular body V2.jpg"
    Case "FEMININE"
        SelectSubPackage "40 Body normal map 1 - Feminine"
        Break
    Case "FEMININE TONED"
        SelectSubPackage "40 Body normal map 2 - Feminine Arms Toned Abs"
        Break
    Case "MUSCULAR"
        SelectSubPackage "40 Body normal map 3 - Muscular body"
        Break
    Case "MUSCULAR V2"
        SelectSubPackage "40 Body normal map 4 - Muscular body V2"
        Break
EndSelect

SelectOne "CHOOSE A FACE SET YOU WANT TO INSTALL",\
    "|NAVETSEA FACE SET","\n\nCHOOSE WHICH FACE SET YOU REQUIRE\n\nCLICK NEXT TO CONTINUE THE INSTALLATION","FOMod\\images\\Face Base Textures Set.jpg",\
    "FULLER LIPS FACE SET","\n\nCHOOSE WHICH FACE SET YOU REQUIRE\n\nCLICK NEXT TO CONTINUE THE INSTALLATION","FOMod\\images\\Face Base Textures Set Fuller Lips.jpg",\
    "NUSKA REAL SKIN FACE SET","\n\nCHOOSE WHICH FACE SET YOU REQUIRE\n\nCLICK NEXT TO CONTINUE THE INSTALLATION","FOMod\\images\\Face Base Textures Nuska Real Skin Set.jpg",\
    "NUSKA REAL SKIN FRECKLES FACE SET","\n\nCHOOSE WHICH FACE SET YOU REQUIRE\n\nCLICK NEXT TO CONTINUE THE INSTALLATION","FOMod\\images\\Face Base Textures Nuska Real Skin Freckles Set.jpg"
    Case "NAVETSEA FACE SET"
        SelectSubPackage "50 Face Base Textures Set"
        NavBaseFace = True
        Break
    Case "FULLER LIPS FACE SET"
        SelectSubPackage "50 Face Base Textures Set Fuller Lips"
        NavBaseFace = True
        Break
    Case "NUSKA REAL SKIN FACE SET"
        SelectSubPackage "50 Face Base Textures Set Nuska Real Skin"
        NuskaBaseFace = True
        Break
    Case "NUSKA REAL SKIN FRECKLES FACE SET"
        SelectSubPackage "50 Face Base Textures Set Nuska Real Skin Freckles"
        NuskaBaseFace = True
        Break
EndSelect

If NavBaseFace
    SelectMany "OPTIONAL: TICK A COMBINATION OF THE FOLLOWING - OR NONE OF THEM",\
        "FULL LIPS MORE CHARACTER ADDON","\nOPTIONAL: THESE MODIFY THE NAVETSEA FACE SET YOU HAVE ALREADY CHOSEN.\n\nCHOOSE EITHER OF THE ADDONS, YOU CAN ALSO CHOOSE THE MORE OPAQUE LIPTINT MASK TO GO WITH THE ADDON CHOSEN, OR NOT, OR NONE OF THEM\n\nCLICK NEXT TO CONTINUE THE INSTALLATION","FOMod\\images\\Face Addon Fuller Lips more character.jpg",\
        "FULL LIPS WITH MAKE-UP ADDON","\nOPTIONAL: THESE MODIFY THE NAVETSEA FACE SET YOU HAVE ALREADY CHOSEN.\n\nCHOOSE EITHER OF THE ADDONS, YOU CAN ALSO CHOOSE THE MORE OPAQUE LIPTINT MASK TO GO WITH THE ADDON CHOSEN, OR NOT, OR NONE OF THEM\n\nCLICK NEXT TO CONTINUE THE INSTALLATION","FOMod\\images\\Face Addon Fuller Lips with makeup.jpg",\
        "DARKER LIPTINT MORE OPAQUE","\nOPTIONAL: THESE MODIFY THE NAVETSEA FACE SET YOU HAVE ALREADY CHOSEN.\n\nCHOOSE EITHER OF THE ADDONS, YOU CAN ALSO CHOOSE THE MORE OPAQUE LIPTINT MASK TO GO WITH THE ADDON CHOSEN, OR NOT, OR NONE OF THEM\n\nCLICK NEXT TO CONTINUE THE INSTALLATION","FOMod\\images\\Darker liptint mask - More opaque lip color.jpg"
        Case "FULL LIPS MORE CHARACTER ADDON"
            SelectSubPackage "60 Face Addon Fuller Lips more character"
            Break
        Case "FULL LIPS WITH MAKE-UP ADDON"
            SelectSubPackage "60 Face Addon Fuller Lips with makeup"
            Break
        Case "DARKER LIPTINT MORE OPAQUE"
            SelectSubPackage "70 Darker liptint mask - More opaque lip color"
            Break
    EndSelect
EndIf

If NuskaBaseFace
    SelectMany "OPTIONAL: THE FOLLOWING CAN BE USED WITH NUSKA FACE - OR NOT",\
        "DARKER LIPTINT MORE OPAQUE","\nTHESE LIPTINT MASKS CAN BE USED TO MODIFY THE NUSKA FACE SET YOU HAVE ALREADY CHOSEN.\n\nCHOOSE IT, OR NOT IF YOU PREFER JUST NUSKA FACE WORKING WITH VANILLA LIPTINT MASKS INSTEAD\n\nCLICK NEXT TO CONTINUE THE INSTALLATION","FOMod\\images\\Darker liptint mask - More opaque lip color.jpg"
        Case "DARKER LIPTINT MORE OPAQUE"
            SelectSubPackage "70 Darker liptint mask - More opaque lip color"
            Break
    EndSelect
EndIf

;== Select Old Folk Normals ==

SelectOne "CHOOSE OLD FOLK NORMAL MAPS",\
    "OLD FOLK - NAVETSEA YOUNGER","\n\nCHOOSE THIS OPTION TO INSTALL NAVETSEAS OLD FOLK NORMAL MAPS ( YOUNGER LOOKING ).\n\nCLICK NEXT TO CONTINUE THE INSTALLATION","FOMod\\images\\Old Folk Normals - Navetsea.jpg",\
    "|OLD FOLK - VANILLA","\n\nCHOOSE THIS OPTION TO KEEP VANILLA OLD FOLK NORMALS\n\nCLICK NEXT TO CONTINUE THE INSTALLATION","FOMod\\images\\Old Folk Normals - Vanilla.jpg"
    Case "OLD FOLK - NAVETSEA YOUNGER"
        SelectSubPackage "80 Old Folk Normals - Navetsea younger"
        Break
    Case "OLD FOLK - VANILLA"
        Break
EndSelect

;== Finish Page ==

Note "\nCHECK SELECTION ABOVE, IF NOT HAPPY USE THE BACK BUTTON .. WHEN READY, TICK 'APPLY THESE SELECTIONS' BELOW, AND THEN FINISH.\n\nIF YOU HAVE AUTO-ANNEAL/INSTALL WIZARDS SET IN WRYE BASH INSTALLER PREFERENCES .. THE WIZARD WILL INSTALL YOUR SELECTIONS AFTER CLICKING FINISH - OTHERWISE, RIGHT CLICK THE INSTALLER AGAIN AND CHOOSE INSTALL"

 

Link to comment
Share on other sites

Heard back from Mangaclub today. He'll likely be updating Vivid Weathers with the new archive I sent him soon. ;)

  • Like 2
Link to comment
Share on other sites

21 hours ago, alt3rn1ty said:

The "If Blag" near the end there is asking if blag is true, if it is "Do other action" happens. If it is still false "Do other action" doesn't happen. You dont need to put "If blag == true", just "If blag"

 

 

Very good. I got that down (I learned a ton from this specific wizard when I was just starting out).

What I'm running into is:  if I have three variables and want to test or calculate the value of all three of them, for example:

Variable = 1 + 2 + 3

or

If  bCondition1 == True AND bCondition2 == False AND bCondition3 == False

The right-most value is always ignored or lopped off.  For example the top one would set the value as 3 (1+2)  and the bottom one will be as if "bCondition1 and bCondition2" were the only things being evaluated.

I know I have to be doing something wrong, then again I've compared tons of values together successfully before in the "Sounds of Skyrim" wizard:

If GetEspmStatus("EnhancedLightsandFX.esp") > 1 and GetEspmStatus("ELFXEnhancer.esp") < 1 and GetEspmStatus("ELFX - Hardcore.esp") < 1 and GetEspmStatus("ELFX - Weathers.esp") < 1
    sModName201 = "|" + sModName201
EndIf

But in the SoS case, the evaluation of "GetEspmStatus" is done right there in the "If" statement and it isn't testing on a variable passed to it that was set earlier in the script.

I may be running afoul of some Pythonesque (not Monty) rule inherent in the scripting language that I'm not aware of.

Link to comment
Share on other sites

9 minutes ago, TechAngel85 said:

Heard back from Mangaclub today. He'll likely be updating Vivid Weathers with the new archive I sent him soon. ;)

Splendid! That's fantastic. :)

 

Link to comment
Share on other sites

7 hours ago, Beermotor said:

Very good. I got that down (I learned a ton from this specific wizard when I was just starting out).

What I'm running into is:  if I have three variables and want to test or calculate the value of all three of them, for example:


Variable = 1 + 2 + 3

or


If  bCondition1 == True AND bCondition2 == False AND bCondition3 == False

The right-most value is always ignored or lopped off.  For example the top one would set the value as 3 (1+2)  and the bottom one will be as if "bCondition1 and bCondition2" were the only things being evaluated.

I know I have to be doing something wrong, then again I've compared tons of values together successfully before in the "Sounds of Skyrim" wizard:


If GetEspmStatus("EnhancedLightsandFX.esp") > 1 and GetEspmStatus("ELFXEnhancer.esp") < 1 and GetEspmStatus("ELFX - Hardcore.esp") < 1 and GetEspmStatus("ELFX - Weathers.esp") < 1
    sModName201 = "|" + sModName201
EndIf

But in the SoS case, the evaluation of "GetEspmStatus" is done right there in the "If" statement and it isn't testing on a variable passed to it that was set earlier in the script.

I may be running afoul of some Pythonesque (not Monty) rule inherent in the scripting language that I'm not aware of.

Not sure- is there an extra space after the if in the condition? The parser is very paranoid about spaces.

Link to comment
Share on other sites

3 hours ago, lmstearn said:

Not sure- is there an extra space after the if in the condition? The parser is very paranoid about spaces.

I just free-handed that as an example; I probably just hit the space bar twice by accident. :)

 

Link to comment
Share on other sites

14 hours ago, TechAngel85 said:

Heard back from Mangaclub today. He'll likely be updating Vivid Weathers with the new archive I sent him soon. ;)

@TechAngel85

I have a gift for you: Farmhouse Chimneys SSE Wizard.txt

I really dig this mod so I got a wild hair and whipped a wizard up for it, despite the fact it doesn't technically need one.

It is fairly well tested but I don't have Falskaar (:sleeping:) so I didn't explicitly test with it present. 

EDIT: One last thing before I forget - I did make a small change to the description on the parallax meshes: so far the only forward movement I've heard of on parallax occlusion mapping has been on the ReShade side of the shader world, but AFAIK it doesn't work like the DX9 ENB stuff did.  DX11 has far better hardware tessellation support so maybe we'll see something sooner or later.

Link to comment
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now
×
×
  • Create New...